이 문서를 게시하거나 프린트하려면 위 문서출처를 반드시 포함해야 합니다.
파일 핸들 (File Handle)
앞 글에서 사용자 입력처리에 관해서 알아본 적이 있습니다. 혹시 그 글을 안 읽으신 분은 지금 읽고 오시기 바랍니다.
그 글에 보시면 < > 사이에 파일핸들을 넣으면 파일을 한 줄 읽어들인다는 말씀을 드렸었는데요. 파일핸들이 뭔지를 우선 알아봅시다.
Llama book 에 보면, 파일핸들은 "바깥 세계와 펄 프로세스 사이의 I/O connection" 이라고 되어 있습니다. 바깥 세계 라는 것은 하드디스크등에 물리적으로 저장된 파일을 얘기합니다. 그 파일과 펄 프로그램내의 프로세스 사이에 데이타를 넣고 뺄 수 있는 (I/O) 하나의 연결을 만들 수가 있는데 이걸 파일 핸들이라고 합니다. 말로 하면 복잡하니까 예를 들어서 보죠.
open MYFILE, "logfile.txt";위의 코드는 open() 이라는 함수를 이용해서 logfile.txt 라는 파일을 MYFILE 이라는 파일핸들로 여는 코드 입니다. 이렇게 연 다음, 펄 프로그램내에서 이 MYFILE 파일핸들을 이용해서 logfile.txt 파일의 내용물을 읽어온다거나 (Input), logfile.txt 에 다른 데이타를 기록 (Output) 할 수가 있는 것입니다. 문자그대로 실제 파일을 펄 프로그램내에서 다루기 위해 사용하는 '핸들'인 것입니다.
파일핸들을 만드는 방법은, 다른 펄 변수와 달리 앞에 붙는 문자 ($, @, %) 가 없다는 점만 지켜주시면 됩니다. 그런데 파일핸들은 관용적으로 대문자만 사용하는 것이 보통입니다. 소문자로 쓸 경우 펄의 예약어 (reserved word) 와 충돌할 가능성이 있기도 하고, 또 대문자로 쓰면 두드러져 보이기 때문이라고 합니다.
위의 코드에서 보신 것처럼 펄에서 파일핸들을 이용해서 파일을 열때 사용하는 함수가open() 함수 입니다. 이런 형식이죠.
open FILEHANDLE, "filename" 이때 파일을 여는 모드(mode) 가 크게 3 가지 정도가 (자세히 들어가면 더 많습니다만) 있습니다.
open FH1, "myfile";
open FH2, ">newfile";
open FH3, ">>logfile";
첫번째 것은 myfile 을 '읽기모드' 로 연것입니다.
문자그대로 myfile 이라는 파일의 내용물을 읽어들이기 위해서 myfile 을 FH1 으로 연 것이죠.
파일을 읽는 것은 밑에서 더 자세히 얘기드리겠습니다.
그 다음, 파일 이름 앞에 > 을 한 개 붙인 것은 '쓰기모드' 중 덮어쓰기 (overwrite) 모드 입니다. 파일에 어떤 내용을 기록하기 위해 열때 사용하는 것인데 특징적으로 기존의 내용을 다 없애버리고 새로운 내용으로 덮어쓰기를 하는 모드 입니다. 위 코드의 경우, newfile 이란 파일이 없다면 새로 만들어서, 있다면 기존의 내용을 지우고 덮어쓰기를 하게 되는 것입니다.
세번째, 파일이름 앞에 >> 을 붙이면 이것은 쓰기모드 중 붙여쓰기 (append) 모드로 여는 것입니다.파일을 열어서 기존의 내용 끝에 새로운 내용을 덧붙일때 사용하는 모드 입니다. 위의 코드의 경우, logfile 이라는 파일이 없다면 새로 만들어서, 있다면 열어서, 기존의 내용은 그대로 두고 기존 내용 끝에 새로운 내용을 덧붙일 수 있게 준비하는 것입니다.
파일의 읽기 쓰기에 대해서는 밑에서 자세히 다루게 되구요, 우선은 위에서 보신 것처럼 파일을 3가지 방식으로 열어서 준비를 할 수 있다고 파악하시면 됩니다.
open() 은 펄 프로그램이 직접 파일을 여는 것이 아니라 운영체계에 파일을 열어달라고 요청만 하는 함수 입니다. 따라서 운영체계에서 파일을 열 수 없다고 판단되는 경우 (퍼미션이 안맞다든지, 요청한 파일이 존재하지 않는다든지) open() 은 거짓 (0) 을 리턴하게 됩니다. 이때 파일을 여는데 실패한 것이 드러나는 경우도 있지만 드러나지 않는 경우도 있구요. 그 경우 프로그램은 분명히 제대로 동작하지 않는데 특별한 에러 메씨지는 없는 그런 일이 생길 수 있을 겁니다. 따라서 우리는 open() 이 성공했는지 아닌지를 확인할 필요가 있습니다. 그럴때 사용하는 것이 바로 die() 입니다.
이렇게 사용합니다.
open (HANDLE, "myfile") or die ("Can't open myfile: $!"); 
open (HANDLE , "myfile") || die "Can't open myfile: $!";
두개는 거의 같은 것으로 생각하시면 됩니다. 읽는 그대로죠. myfile 이라는 파일을 HANDLE 이라는 파일핸들을 이용해서 읽기모드로 열어라, 만약 열지 못하면 Can't open myfile.. 이라는 메씨지를 보여주면서 프로그램 실행을 중단한다.는 의미 입니다. $! 은 에러의 구체적 내용을 담고 있는 변수 입니다. 더 자세한 에러의 원인을 보여주는 것이죠. 써줘도 되고 안써줘도 됩니다.
파일핸들을 연 다음에 어떤 작업을 하고 닫을 때에는 close(FILEHANDLE) 를 사용하시면 됩니다. close() 는 꼭 해야만 하는 것은 아닙니다. 즉 파일핸들이 더 이상 열려 있을 필요가 없으면 펄이 알아서 닫죠. 하지만 어떤 파일을 동시에 여러곳에서 수정을 하는 것을 처리해주는 파일 잠그기 (file locking; 다음에 자세히 다룹니다) 를 할때 이 close() 가 특별한 의미를 갖게 됩니다. 일단은 꼭 닫아줘야 하는 것은 아니다 정도로만 알고 넘어가시면 될것 같군요.
자 이제 파일을 열어서 어떤 일을 할 수 있는지 하나 하나 알아보죠. 먼저,
파일 읽기
사용자 입력 처리에서 공부해본 것 처럼 표준 입력으로부터 한 줄을 읽어들여서 \n 을 떼어내고 어떤 변수에 저장하는 것은,
chomp($line = <STDIN>);처럼 하면 된다고 했습니다.
그러면 표준입력으로부터 여러 줄을 읽는 것은 어떻게 될까요?
while(defined($line=<STDIN>)) {
print $line;
}
defined 라는 것은 변수에 어떤 값이 할당되어 있으면 1 을 리턴하고 그렇지 않으면 0 을 리턴하는 함수입니다.따라서 위의 코드는 표준입력으로부터 한 줄을 읽어들여서 $line 에 할당을 할 수 있다면 (즉 읽어들일 줄이 있다면) while 루프내의 구문을 실행한다는 의미가 되죠. 만약 표준입력으로부터 읽어들일것이 더 이상 없다면 $line 은 undefined 가 되고, while () 은 거짓이 되어서 while 루프가 끝나는 것입니다.
그런데 STDIN 자리에 파일핸들을 넣을 수가 있다고 했쟎아요. 즉 어떤 파일을 열어서 그 파일에 '줄' 이 있는 한은 계속해서 읽어들일 수가 있는 것입니다.
따라서 myfile.txt 라는 파일을 열어서 그 파일의 내용을 그대로 다 출력해주는 코드는,
open MYHANDLE, "myfile.txt";
while(defined($line=<MYHANDLE>) {
print $line;
}
이 될 것입니다.
그런데 이렇게 파일을 열어서 읽는 기능은 매우 매우 자주 사용하는 기능이기 때문에, 펄에는 당연히 관용적으로 쓰이는 축약형 코드가 있습니다. 바로 이겁니다.
open MYHANDLE, "myfile.txt";
while(<MYHANDLE>) {
print $_;
}
while() 안에 바로 <FILEHANDLE> 을 집어넣은 것입니다. 이것을 풀어서 설명해 보면, myfile.txt 에 읽어들일 내용이 있는 한 <MYHANDLE>은 참일것이고, while 루프내의 구문이 계속 실행하게 됩니다. 위의 경우는 파일핸들로부터 읽어들인 줄을 명시적으로 어떤 변수에 할당하지 않았으므로 펄의 default variable 인 $_ 에 담기게 되는 것이구요.
위와 같은 코드를 이용해서 파일을 읽기모드로 열고, 그 파일의 각 줄을 $_ 을 통해서 다룰 수가 있는 것입니다. 아주 자주 쓰이는 것이므로 외워두면 좋습니다. 여기서 끝이냐. 그렇다면 펄이 아니죠.-_-;
한 번 더 줄일 수 있습니다.
open MYHANDLE, "myfile.txt";
print while (<MYHANDLE>);
위 코드 역시 myfile.txt 라는 파일을 열어서 그 내용을 쭉 출력해주는 코드 입니다. 훨씬 간단하죠? 간단할 뿐만 아니라 일반적인 영어 문장처럼 자연스럽게 읽힙니다. MYHANDLE 을 읽어올 수 있는 한은 (while) 프린트 해라. .
위와 같은 스타일이 능숙한 펄 코딩 스타일 입니다.
비슷한 것으로 < > 을 리스트 컨텍스트에서 사용한 것도 있습니다.
foreach (<FILEHANDLE>) {
print $_;
}
또는,
for $line (<FILEHANDLE>) {
print $line;
}
for() 나 foreach() 는 괄호안을 리스트처럼 다루는 리스트 컨텍스트 입니다. 따라서 첫번째 코드는 FILEHANDLE 을 리스트 컨텍스트에서 읽어들여서 각 줄을 출력해주는 것입니다. 결과적으로는 while 루프와 같을지 몰라도 내부적으로는 다른 것이죠. 리스트 컨텍스트에서 읽어들일때는 FILEHANDLE 이 가르키는 파일을 우선 처음부터 끝까지 다 읽어들인 다음에 한 줄씩 한줄씩 루프를 돌리게 됩니다만 while 의 경우는 한 줄 읽어서 루프내 구문을 실행하고, 그 다음 줄을 읽어서 루프내 구문을 실행하고,. . . . 진행되는 것입니다. 라마북에 나온 얘기대로 만약 수백메가 바이트에 이르는 로그파일을 연다고 생각해보면, 이것을 처음부터 끝까지 다 읽어들인 다음에 루프를 돌리는 for 나 foreach 의 경우는 한줄씩 읽어들이는 while 에 비해 프로그램 실행속도가 현저히 떨어질 수 있는 것입니다.
for() 나 foreach() 코드 역시 축약 가능 합니다. 이렇게요.
open (FI, "myfile") || die ("can't open myfile");
print for (<FI>);
파일을 읽어들이는 것은 이해가 되시죠?
파일 쓰기
파일쓰기 역시 읽기와 똑같습니다. 단 열때 쓰기모드로 연다는 것만 다른 것이죠.
파일쓰기는 print() 함수를 사용합니다.
예를들어 myfile 이라는 파일을 새로 만들어서 뭔가를 쓰려면,
open (FH, ">myfile") || die ("Can't open myfile");
print FH "It's a beautiful day !";
print 다음에 파일핸들을 써주고, 써넣을 내용을 적어주는 것이죠.
print 다음에 파일핸들을 생략하면 특정 파일에 쓰기를 하는 것이 아니라 default 인 표준출력 (일반적으로 모니터) 에 결과를 띄워주게 됩니다.
파일을 붙여쓰기 모드로 열어서 새로운 내용을 파일 끝에 첨가할 수도 있을 것입니다.
open (FH2, ">>myfile") || die "Can't open myfile";
print FH2 "2002/9/1 : 오늘 추가한 내용입니다";
간단하죠?
예를들어 웹싸이트 방문객 로그파일을 만드는 코드 중 일부는 이렇게 하면 될 겁니다.
open (LOG, ">>logfile.txt") || die ("Can't open logfile.txt");
print LOG "$ENV{'REMOTE_ADDR'}|$ENV{'HTTP_USER_AGENT'}\n";
$ENV{'REMOTE_ADDR'} 등의 환경변수는 펄을 이용한 cgi 개발 글을 참고하시구요. 위의 코드는 로그파일을 붙여쓰기 모드로 열어서 각 줄에 "접속자 ip주소|사용 웹브라우져" 로 기록해줍니다.
읽기 쓰기 모드
위에서 파일을 읽기모드, 쓰기모드로 여는 방법을 알아 보았습니다.
하지만 이런 경우도 있지 않겠습니까.
예를들어 어떤 파일을 열어서 그 내용 중 일부를 고치고 싶은 경우, 읽기모드로 열어서는 내용을 고칠 수가 없을 것이고 쓰기모드로 열어서는 기존의 내용이 없어져 버리거나 끝에 새로운 내용을 덧붙이는 것 정도밖에 할 수가 없습니다.
이럴때 쓰는 모드가 있습니다.
open FILEHANDLE, "+<myfile";
이것은 파일을 열어서 그 내용을 읽어올 수 있을 뿐만 아니라, 파일에 쓰기 (내용수정) 도 할 수 있습니다. 한가지 조심하실 점은 myfile 이라는 파일이 없는 경우 새로운 파일을 만들지는 못한다는 점 입니다.
이 모드는 다음에 텍스트 데이타베이스를 다룰때 한 번 더 자세히 살펴보도록 하겠습니다.
파일 테스트
파일테스트 라는 것은 문자그대로 파일을 테스트 해보는 것입니다. 어떤 파일이 읽을 수 있는 파일인지, 어떤 파일이 쓰기가 가능한 파일인지, 어떤 파일의 크기가 100k 이상인지, 어떤 파일이 만들어진지 10 일이 안되었는지 등등등을 테스트 해볼 수 있는 것이죠. 방법은 간단합니다. if 다음에 파일테스트문을 붙여주면 되구요, 파일테스트는 이런 것들이 있습니다.
| -e | 파일이나 디렉토리가 존재하는지 |
| -r | 파일이나 디렉토리가 읽을 수 있는 것인지 |
| -w | 파일이나 디렉토리가 쓰기 가능 한지 |
| -x | 파일이나 디렉토리가 실행 가능 한지 |
| -o | 파일이나 디렉토리가 현재 유져의 소유인지 |
| -f | 이것이 파일인지 |
| -d | 이것이 디렉토리인지 |
| -l | 이것이 심볼릭 링크인지 |
| -M | 수정한지 며칠 되었는지 |
| -A | 억세스 된지 며칠 되었는지 |
이외에도 몇가지 더 있습니다만.
이렇게 쓰이게 됩니다.
예를들어 위에서 +<< 모드는 파일이 없을때 새로 만들지는 못한다고 했는데요, 파일테스트를 이용하면 이를 해결할 수 있습니다.
if (-e "myfile") {
open (MY, "+<myfile") || die ("Can't open");
}
else {
open (MY, ">myfile") || die ("Can't create")
}
if (-e "myfile") 이라는 것은 myfile 이라는 파일이 있느냐를 테스트 하는 것입니다. myfile 이 존재하면 if() 괄호안은 참이 되는 것이죠.
다른 예로, 어떤 디렉토리내의 html 파일들 중 수정한지 5일 이상인 파일들만 따로 모으고 싶다면,
@files = glob("*.html");
foreach $file (@files) {
if (-M $file > 5) {
push @old_files, $file
}
}
print "@old_files";
glob("*.html") 에 대해서는 아직 말씀 안드렸지만, 우선은 어떤 디렉토리내의 확장자가 html 인 파일들의 이름들을 리스트 형태로 반환하는 것이라고 아시면 무리가 없을 것 같습니다.
기본적인 디렉토리 작업
기본적인 디렉토리 작업에는 다른 디렉토리로의 이동, 디렉토리 만들기, 디렉토리 없애기 등이 있습니다. 각각을 알아보면,
1. 디렉토리 이동
디렉토리 이동은 (유닉스 쉘 명령어 cd 와 똑같은 기능) 이렇게 합니다.
chdir "/bin" or die ("can't change directory");주의하실 점은 윈도우즈에서 사용하실 때도 유닉스 방식으로 디렉토리 패쓰를 써줘야 한다는 것입니다.
예를들어, C 드라이브에 있는 WINNT 라는 디렉토리로 이동하려고 한다면,
chdir "C:/WINNT" or die ("can't change directory");가 됩니다. C:\WINNT 하면 에러가 나죠. 조심하세요.
2. 디렉토리 만들기
역시 쉘 명령어와 똑같습니다.
mkdir "backup", 0755 || die "can't create directory";위 코드는 퍼미션이 755 이고, 이름이 backup 인 디렉토리를 현재 펄 프로그램이 저장된 디렉토리내에 만드는 코드 입니다. 퍼미션에 대한 자세한 설명은 이 글의 주제와 좀 벗어나므로 생략하겠습니다. 한가지 주의하실 점은 755 앞에 꼭 0 을 붙여서 0755 로 해야 한다는 것입니다. 왜 그럴까요. 우리가 스케일라 변수 에서 살펴본 것처럼 펄은 숫자를 파악할때 맨 첫숫자가 0 으로 시작하는 숫자만 8진수로 알아보기 때문입니다. 만약 755 라고만 해놓으면 펄은 이것을 십진수 755 로 알게 되죠.
3. 디렉토리 없애기
내용물이 없는 디렉토리의 경우에는 이렇게 하시면 됩니다.
rmdir "temp" or die "can't delete temp directory";하지만 내용물이 있는 경우엔 위 코드로 지워지지 않습니다. 그러면 내용물이 있는 디렉토리는 어떻게 지울까요? 아마 이 글을 다 읽고 나시면 스스로 코딩을 해내실 수 있을 겁니다. 디렉토리 내의 파일을 다 지운 다음 디렉토리를 지우면 되죠.
보신 것처럼 대체로 유닉스 명령어와 매우 유사하다는 것을 알 수 있습니다. 바로 이런 면들이 펄을 유닉스에 더욱 깊숙히 뿌리 내리게 한것이죠. 기존의 유닉스 지식을 그대로 지렛대로 활용할 수 있으니까요.
Globbing
디렉토리내에 있는 파일들 중에 특정 확장자의 파일만 따로 모아야 할 경우가 많이 있습니다. 이처럼 파일 이름이 어떤 패턴에 맞는 것만 모으는 것을 globbing 이라고 합니다. 펄에서는 glob "pattern"; 의 형태로 쓰시면 됩니다. 예를들어 내 문서 디렉토리로 이동해서 확장자가 .txt 인 파일들의 이름만 따로 모으고 싶다면,
chdir "/home/linuxer/doc" || die "can't cd";
@text_files = glob "*.txt";
print "@text_files";
@text_files 내에는 확장자가 .txt 인 파일들의 이름이 들어가 있게 됩니다. glob " " 내에는 여러가지 패턴을 쓸 수 있습니다. 예를들어 확장자가 .html 인 파일 중 b 로 시작하는 파일만 모으고 싶다면,
@b_files = glob "b*.html";로 하시면 됩니다. 또한 따옴표내에서는 variable interpolation 이 가능하므로 변수 이름을 사용하실 수도 있습니다. 이렇게요.
$mydir = "/home/linuxer/";
@mp3 = glob "$mydir/*.mp3";
일반적인 큰 따옴표와 마찬가지죠.
다른 예를 하나 더 들어볼까요?
만약 어떤 디렉토리내의 파일 중에 executable 한 파일만 모으고 싶다면, 앞시간에 배운 파일테스트를 활용해서 이렇게 하시면 됩니다.
@files = glob "*";
foreach $file (@files) {
push @xcutable, $file if -x $file
}
print "@xcutable";
foreach 안의 push 구문이 혹시 조금 생소해 보이시는지요?
그 구문은,
if (-x $file) {
push @xcutable, $file
}
와 똑같은 것입니다. 한 줄로 쓰니까 훨씬 간소해지죠? 바로 위와 같은 스타일이 펄 코딩 스타일 입니다. 처음에는 if ( ) { } 형태로 차근차근 코딩해서 익히시는게 좋겠지만 익숙해지고 나면 위와 같이 한 줄로 줄여서 코딩하는 것도 좋습니다. 우선 코드가 간단해지구요, 자세히 보시면 자연어 (비록 영어지만) 와 굉장히 유사한 형태로 코딩이 될 수 있다는 것을 느끼실 수 있을 겁니다.
딱 "만약 .. 라면 .. 해라" 의 형태이지 않습니까? 일상어를 구사하는 식으로 쭉 코딩을 할 수 있는 것입니다. 언어학자가 만든 프로그래밍 언어라는 것이 이런데서 드러납니다.
같은 식으로 위의 코드는 다음과 같이 더 줄일 수도 있습니다. glob "*" 을 아예 if () 안에 집어넣을 수 있습니다.
foreach $file (glob "*") {
push @xcutable, $file if -x $file
}
print "@xcutable";
음. . There is more than one way to do it. 아시죠?
참고로, 좀 오래된 펄 코드에서는 파일이름 글로빙을 glob 대신 <> 을 이용한 경우가 많이 있습니다. <> 사이에 패턴을 넣은 것이죠. 이런 방식은 파일핸들 읽어들이는것과 헷깔리니까 가급적 사용하지 마시구요. 다른 사람의 코드를 읽기 위해서 그냥 알아두시기만 하면 되겠습니다. 이런겁니다.
@files = </home/linuxer/*.mp3>;
@files = glob ("/home/linuxer/*.mp3");
두개는 같은 것입니다.
그리고, glob "" 은 파일이름을 a,b,c.. 순서로 반환 합니다. 좋은 점이죠? 또 하나의 특징은 invisible file (점으로 시작하는 파일) 들의 이름은 담기지 않는다는 점 입니다.
glob "" 대신에 디렉토리 핸들을 쓸 수도 있습니다. 디렉토리 핸들은 파일핸들 과 유사 합니다. 단지 open() 대신엔 opendir() 를 쓰고, 디렉토리내의 파일이름은 readdir() 를 이용해서 읽어온다는 점이 다릅니다.
$dir = "/usr/local/bin";
opendir DH, $dir || die "can't open";
# 디렉토리 핸들 DH 로 "/usr/local/bin" 을 열고
@files = readdir DH; # 디렉토리 핸들을 읽어서 @files 에 담고
foreach $file (@files) {
print "$file\n"
}
glob "" 과 다른 점은 숨겨진 파일 (invisible file) 까지 다 읽어온다는 점 입니다.
계속해서 파일 다루는 것과 관련된 내용을 알아봅시다.
파일 다루기
1. 파일 지우기
파일을 지우려면,
unlink "temp1";rm 가 아닙니다. unlink 입니다. unlink 에 의해서 반환되는 값은 지워진 파일의 갯수 입니다.
만약 tmp 라는 디렉토리에 있는 파일 중 10일 이상 억세스 되지 않은 파일들만 다 지우려면,
chdir "/home/linuxer/tmp" || die "can't cd";
@files = glob "*";
foreach $file (@files) {
unlink $file if -A $file > 10
}
2. 파일 이름 바꾸기
rename 입니다.
rename "old" , "new";라마북에 아주 좋은 예가 있네요. 어떤 디렉토리내의 파일 중 확장자가 .txt 인것을 .html 로 바꾸고 싶다면,
foreach my $old_name (glob "*.txt") {
my $new_name = $old_name;
$new_name =~ s/\.txt$/.html/;
if (-e $new_name) {
warn "can't rename $old_name to $new_name: $new_name exists !\n";
}
elsif (rename $old_name, $new_name) {}
else {
die "rename failed :$!\n";
}
}
뭐 아주 평이한 코드죠. elsif 부분은 주의해서 보시기 바랍니다. warn 은 die 와 비슷한 것입니다.
3. 퍼미션 바꾸기
chmod 0755 , "*.pl";
똑같습니다. 그쵸?
4. 파일 카피
간단한 방법으로는 시스템 함수 cp (도스의 경우는 copy) 를 이용하면 됩니다. system() 함수는 유닉스 쉘 커맨드를 펄 내에서 사용할 수 있게 해주는 함수 입니다.
system ("cp $oldfile, $newfile");
파일 정보
어떤 파일에 관한 모든 정보를 한꺼번에 알려주는 함수가 있습니다. 바로 stat() 함수 입니다.
my ($dev, $ino, $mode, $nlink, $uid, $gid, $rdev, $size,
$atime, $mtime, $ctime, $blksize, $blocks) = stat($filename);
보신 것처럼 파일이름을 넣어주면 그 파일의 파일시스템의 device number, inode number, mode (파일 타입과 퍼미션), 하드링크의 갯수, user-ID, group-ID, device identifier, 파일의크기(바이트 단위), 억세스된 시간, 변경된 시간, inode 변경시간, 파일시스템 I/O 를 위해 필요로하는 블럭크기, 실제로 할당된 블럭크기 등이 리턴 됩니다. 그야말로 총체적인 파일 정보를 다 얻어내는 것이죠. 조금 유닉스 스페시픽한 부분이긴 합니다만은.
위에서 파일을 변경한 시간, 억세스한 시간등을 알 수 있다고 했는데요.
조금 더 자세히 알아보겠습니다.
예를들어 index.html 이라는 파일의 변경한시간, 억세스한 (읽은) 시간을 출력해주는 코드는 이렇게 됩니다.
my ($atime, $mtime) = ((stat("index.html"))[8,9];
print "$atime\n$mtime\n";
이 코드에서 주의하실 점은요, stat() 에 의해 반환되는 여러 파일 정보 중 9번째, 10번째가 바로 억세스한 시간, 변경한 시간이기 때문에 [8,9] 이 된 것이구요. (배열은 0 부터 센다고 했습니다.) 하나 특기할만한 것은 stat() 앞뒤를 또 하나의 괄호로 감쌌다는 점입니다. 그 괄호를 빼면 위 코드는 에러가 납니다. 왜냐. 어떤값, 변수에 괄호를 씌우는 것은 그 값/변수를 배열로 취급하겠다는 것을 의미합니다. 즉 괄호로 감싸진 것은 리스트 컨텍스트가 된다는 것이죠. 위의 경우 stat() 에 의해 반환된 값들은 부가적인 괄호에 의해 리스트로 취급될것이고, 그 결과 (list)[8,9] 의 형태가 될 수 있는 것입니다. 이해되시죠? 괄호로 감싸면 리스트 컨텍스트가 됩니다. 잊지 마세요.
다시 주제로 돌아와서, 위 코드를 실행해보면 이런 식으로 나옵니다.
1031069374
1030907766
시간이 이런 형태로 나오면 바로 활용하기는 어렵겠죠? 이 시간은 1970년 자정을 기점으로 해서 초단위로 센 숫자들 입니다. 이런 숫자를 우리가 쉽게 사용할 수 있는 형태로 바꿔주는 함수가 localtime() 함수 입니다.
이를테면 1031069374 를 우리가 알 수 있는 형태로 바꾸려면,
$atime = 1031069374;
my ($sec, $min, $hour, $day, $mon, $year, $wday, $yday, $isdst) = localtime $atime;
그런데 이렇게 해도 우리가 생각한 것과 약간 다릅니다.
첫째, $mon 의 경우 '월' 을 알려주긴 하지만 0 부터 11 까지로 셉니다.
둘째,$year 역시 끝 2자리만을 알려줍니다. 예를들어 1989 년 이면 89 가 담기는 것이죠. (2002 년의 경우 102 가 담깁니다) 따라서, 우리가 원하는 최종 결과를 위해서는 이렇게 해야 합니다.
$atime = 1031069374;
my ($sec, $min, $hour, $day, $mon, $year, $wday, $yday, $isdst) = localtime $atime;
$mon++;
$year += 1900;
print "$year/$mon/$day , $hour:$min:$sec";
$mon은 1을 더해주고, $year는 1900 을 더해주면 정확한 월,년이 담기게 됩니다.
참고로 $wday 에는 요일이 담기는데요, 월요일은 1, 화요일은 2, 수요일은 3, .. 의 숫자가 담깁니다.
만약 오늘 날짜를 년도/월/일 형태로 출력하려면 이렇게 할 수도 있을 겁니다.
my ($day, $mon, $year) = (localtime)[3,4,5];
$mon++; $year+=1900;
print "$year/$mon/$day";
localtime 에 괄호를 감싸면 현재시간을 리스트 형태로 반환하겠죠? (괄호로 감싸면 리스트 컨텍스트가 된다고 했습니다)
이번 시간에 살펴본 내용은 실제 코딩에서 아주 활용도가 높은 부분입니다.
